defmodule PicturedwarfWeb.PageLive do
  use PicturedwarfWeb, :live_view
  import Mogrify

  @impl true
  def mount(%{"pics" => pictures}, _session, socket) do
    pictures = case pictures do
      [] -> ["picturedwarf.png"]
      _ -> Enum.map(pictures, fn x -> if File.exists?(Path.join([File.cwd!, "img", x])) do x else "error.png" end end)
    end

    {:ok,
      socket
      |> assign(:uploaded_files, pictures)
      |> assign(:resolution, "800")
      |> allow_upload(:picture, accept: ~w(.jpg .jpeg .png .gif), max_entries: 8)
    }
  end

  @impl Phoenix.LiveView
  def handle_event("validate", _params, socket) do
    {:noreply, socket}
  end

  @impl Phoenix.LiveView
  def handle_event("cancel-upload", %{"ref" => ref}, socket) do
    {:noreply, cancel_upload(socket, :picture, ref)}
  end

  def handle_event("res8", _value, socket) do
    {:noreply, assign(socket, :resolution, "800")}
  end

  def handle_event("res12", _value, socket) do
    {:noreply, assign(socket, :resolution, "1200")}
  end

  @impl Phoenix.LiveView
  def handle_event("save", _params, socket) do
    uploaded_files =
      consume_uploaded_entries(socket, :picture, fn %{path: path}, entry ->
        ext = String.downcase(Path.extname(entry.client_name))
        dest = Path.join([File.cwd!, "img", entry.uuid <> ext])
        resolution = socket.assigns[:resolution]
        open(path) |> auto_orient() |> resize_to_limit(resolution<>"x"<>resolution) |> save(path: dest)
        entry.uuid <> ext
      end)
    case socket.assigns[:uploaded_files] do
      ["picturedwarf.png"] -> {:noreply, assign(socket, :uploaded_files, uploaded_files)}
      _ -> {:noreply, update(socket, :uploaded_files, &(&1 ++ uploaded_files))}
    end
  end

  defp error_to_string(:too_large), do: "Too large"
  defp error_to_string(:too_many_files), do: "You have selected too many files"
  defp error_to_string(:not_accepted), do: "You have selected an unacceptable file type"
end