pacman -Qoq /usr/lib/python3.8/ | $paru/yay/whatever -S --rebuild

pkgname=teams-for-linux
pkgver=1.0.5.r10.g7649cac
_nodeversion=12.13.0
pkgrel=1
pkgdesc="Unofficial Microsoft Teams client for Linux using Electron."
arch=("aarch64" "armv7h" "x86_64")
url="https://github.com/IsmaelMartinez/${pkgname}"
license=("GPL3")
depends=("gtk3" "libxss" "nss")
makedepends=("node-gyp" "python2" "yarn" "nvm" "npm" "git")
source=(
  "git+[URL]https://github.com/IsmaelMartinez/${pkgname}"[/URL]
  "${pkgname}.desktop"
)
sha256sums=(
  "SKIP"
  "f33ab4997c329567bbe172fe77ee6cbced5c5d4354e12ef52a89dd702422fded"
)

pkgver() {
  cd "${srcdir}/${pkgname}"
  git describe --long --tags | sed -e 's/^v//' -e 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "${srcdir}/${pkgname}"
  sed 's#webPreferences: {#webPreferences: {\n\t\t\t\tenableRemoteModule: true,#' -i app/mainAppWindow/index.js
}

build() {
  cd "${srcdir}/${pkgname}"
  export npm_config_cache="$srcdir/npm_cache"
  _npm_prefix=$(npm config get prefix)
  npm config delete prefix
  export NVMDIR="$srcdir/nvmdir"
  source /usr/share/nvm/init-nvm.sh
  nvm install ${_nodeversion} && nvm use ${_nodeversion}
  yarn install --non-interactive --cache-folder "${srcdir}/yarn-cache"
  if [[ ${CARCH} == "aarch64" ]]; then
    yarn electron-builder build --arm64 --linux dir
  elif [[ ${CARCH} == "armv7h" ]]; then
    yarn electron-builder build --armv7l --linux dir
  elif [[ ${CARCH} == "x86_64" ]]; then
    yarn electron-builder build --x64 --linux dir
  fi
  # Restore node config from nvm
  npm config set prefix ${_npm_prefix}
  nvm unalias default
}

package() {
  cd "${srcdir}/${pkgname}"

  if [[ ${CARCH} == "aarch64" ]]; then
    _dist_path=${srcdir}/${pkgname}/dist/linux-arm64-unpacked
  elif [[ ${CARCH} == "armv7h" ]]; then
    _dist_path=${srcdir}/${pkgname}/dist/linux-armv7l-unpacked
  elif [[ ${CARCH} == "x86_64" ]]; then
    _dist_path=${srcdir}/${pkgname}/dist/linux-unpacked
  fi

  install -dm755 "${pkgdir}/opt" "${pkgdir}/usr/bin"
  cp -r --preserve=mode "${_dist_path}" "${pkgdir}/opt/${pkgname}"
  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  for _file in "${srcdir}/${pkgname}/build/icons/"*.png
  do
    _filename="$(basename ${_file})"
    install -Dm644 "${_file}" "${pkgdir}/usr/share/icons/hicolor/${_filename%.png}/apps/${pkgname}.png"
  done
  ln -sf "/opt/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
}